PREAMPLIFIER

********************************************************************
*
* AUTHOR:    MICHAEL S. MCCORQUODALE
* SIMULATOR: BERKELEY SPICE3f5
* COPYRIGHT: MICHAEL S. MCCORQUODALE
* MODELS:    12AX7 MODEL COURTESY OF DUNCAN AMPS
*
********************************************************************

***************************** ANALYSIS ***************************** 
*.OP 
*.TRAN   1u   4m    0   2u 
.AC     DEC  10   10  100k
********************************************************************

*************************** MAIN CIRCUIT *************************** 
VA    3     0   DC    350 
VIN   1     0   AC    1      DC   0  SIN(0 100m 1k) 
X1    1     2   3     PREAMP
********************************************************************

************************** PREAMP CIRCUIT ************************** 
* 
*                IN  OUT VA 
*                |   |   | 
.SUBCKT PREAMP   1   3   5 
RG   1   2   68k 
RGB  1   0   1M 
RK   4   0   1.8k 
RA   3   5   100k 
CK   4   0   0.68u 
X1   3   2   4   12AX7 
.ENDS PREAMP 
* 
********************************************************************

*************************** 12AX7 MODEL **************************** 
* 
.SUBCKT 12AX7 A G K 
BLIM    LI    0   V=(URAMP(V(A)-V(K))^ 1.5 )* 0.000016  
BGG     GG    0   V=V(G)-V(K)--0.53056  
BRP1    RP1   0   V=URAMP(-V(GG)* 0.076498 ) 
BRP2    RP2   0   V=V(RP1)-URAMP(V(RP1)-0.999) 
BRPF    RP    0   V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.18  
BGR     GR    0   V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)*-0.013621 ))) 
BEM     EM    0   V=URAMP(V(A)-V(K)+V(GR)* 87.302 ) 
BEP     EP    0   V=(V(EM)^ 1.5 )*V(RP)* 0.00000111  
BEL1    EL1   0   V=URAMP(V(EP)) 
BEL     EL    0   V=V(EL1)-URAMP(V(EL1)-V(LI)) 
BLD     LD    0   V=URAMP(V(EP)-V(LI)) 
BAK     A     K   I=V(EL) 
BGF     GF    0   V=(URAMP(V(G)-V(K)--0.2 )^1.5)* 0.00001  
BG      G     K   I=V(GF)+V(LD) 
CAK     A     K   0.0000000000007  
CGK     G     K   0.0000000000024  
CGA     G     A   0.0000000000017  
.ENDS   12AX7 
* 
********************************************************************

.END